cmake_minimum_required(VERSION 3.13)

# Make warnings trigger errors.
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Werror")

project(pkmnLib)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

if (NOT SCRIPT_PROVIDER)
    message(WARNING "Script provider was not set, using angelscript as default.")
    set(SCRIPT_PROVIDER "angelscript")
endif()

if (WINDOWS)
    SET(CMAKE_SYSTEM_NAME Windows)
    ADD_DEFINITIONS(-D WINDOWS=1)
else()
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -stdlib=libstdc++")
endif(WINDOWS)

message(STATUS "Using:
\t C ${CMAKE_C_COMPILER}
\t C++ ${CMAKE_CXX_COMPILER}
\t CXX ABI ${CMAKE_CXX_COMPILER_ABI}
\t C++ Version ${CMAKE_CXX_STANDARD}")


if (NOT EXISTS ${CMAKE_BINARY_DIR}/conanbuildinfo.cmake)
    message(WARNING "The file conanbuildinfo.cmake doesn't exist, running conan install.")
    string(REPLACE "." ";" VERSION_LIST "${CMAKE_C_COMPILER_VERSION}")
    list(GET VERSION_LIST 0 VERSION)
    list(GET VERSION_LIST 1 MINOR)
    if (NOT MINOR MATCHES 0)
        SET(VERSION ${VERSION}.${MINOR})
    endif()
    if (NOT WINDOWS)
        execute_process(COMMAND conan install ${CMAKE_SOURCE_DIR} --install-folder=${CMAKE_BINARY_DIR} --build missing
                -s compiler=clang -s compiler.libcxx=libstdc++11 -s compiler.version=${VERSION})
    else()
        execute_process(COMMAND conan install ${CMAKE_SOURCE_DIR} --install-folder=${CMAKE_BINARY_DIR} --build missing
                -s compiler=gcc -s compiler.libcxx=libstdc++11 -s compiler.version=${VERSION} -s os=Windows)
    endif()
endif ()
include(${CMAKE_BINARY_DIR}/conanbuildinfo.cmake)
conan_basic_setup()

message(STATUS "Using Conan Libs:")
foreach (_conanLib ${CONAN_LIBS})
    message(STATUS "\t ${_conanLib}")
endforeach()

# Create Core library with files in src/Core
SET(FILE_SOURCE
        "src/Battling/*.cpp"
        "src/Battling/*.hpp"
        "src/Library/*.cpp"
        "src/Library/*.hpp"
        )
if (SCRIPT_PROVIDER STREQUAL "angelscript")
    SET(FILE_SOURCE ${FILE_SOURCE}
            "src/AngelScript/*.cpp"
            "src/AngelScript/*.hpp"
            "extern/angelscript_addons/*.cpp"
            "extern/angelscript_addons/*.h"
            )
endif()
message(STATUS "${FILE_SOURCE}")
file(GLOB_RECURSE CORE_SRC_FILES ${FILE_SOURCE})

add_library(pkmnLib SHARED ${CORE_SRC_FILES})

foreach (_variableName ${CONAN_LIBS})
    message(STATUS "Lib: ${_variableName}")
endforeach()

SET(_LINKS CreatureLibCore CreatureLibLibrary CreatureLibBattling)
SET(_TESTLINKS pkmnLib CreatureLibCore CreatureLibLibrary CreatureLibBattling)

if (SCRIPT_PROVIDER STREQUAL "angelscript")
    SET(_LINKS  angelscript ${_LINKS} )
    SET(_TESTLINKS angelscript ${_TESTLINKS} )
endif()

if (WINDOWS)
    message(STATUS "Using Windows build.")
    set(CMAKE_CXX_FLAGS  "${CMAKE_CXX_FLAGS} -L ${CMAKE_BINARY_DIR}/bin")
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m64 -Wa,-mbig-obj -Wl,-allow-multiple-definition")
    # Statically link libraries we need in Windows.
    SET(_LINKS ${_LINKS} -static-libgcc -static-libstdc++)
    SET(_TESTLINKS ${_TESTLINKS} -static-libgcc -static-libstdc++)
endif (WINDOWS)


target_link_libraries(pkmnLib PUBLIC ${_LINKS})

if (NOT DEFINED CONAN_EXPORTED)
    # Create Test executable
    file(GLOB_RECURSE TEST_FILES "tests/*.cpp" "tests/*.hpp")
    add_executable(pkmnLibTests  ${TEST_FILES} extern/catch.hpp)
    message(STATUS "${_TESTLINKS}")
    target_link_libraries(pkmnLibTests PUBLIC ${_TESTLINKS})

    # Add a definition for the test library
    target_compile_definitions(pkmnLibTests PRIVATE TESTS_BUILD)
endif ()