cmake_minimum_required(VERSION 3.13)

# Make warnings trigger errors.
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Werror")

project(CreatureLib)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

if (NOT EXISTS ${CMAKE_BINARY_DIR}/conanbuildinfo.cmake)
    message(WARNING "The file conanbuildinfo.cmake doesn't exist, running conan install.")
    string(REPLACE "." ";" VERSION_LIST "${CMAKE_C_COMPILER_VERSION}")
    list(GET VERSION_LIST 0 VERSION)
    list(GET VERSION_LIST 1 MINOR)
    if (NOT MINOR MATCHES 0)
        SET(VERSION ${VERSION}.${MINOR})
    endif ()
    set(CONAN_STATIC_C False)
    if (STATICC)
        set(CONAN_STATIC_C True)
    endif (STATICC)

    if (NOT WINDOWS)
        execute_process(COMMAND conan install ${CMAKE_SOURCE_DIR} --install-folder=${CMAKE_BINARY_DIR} --build outdated
                -s compiler=clang -s compiler.libcxx=libstdc++11 -s compiler.version=${VERSION} -o *:shared=True -o *:staticC=${CONAN_STATIC_C})
    else ()
        execute_process(COMMAND conan install ${CMAKE_SOURCE_DIR} --install-folder=${CMAKE_BINARY_DIR} --build outdated
                -s compiler=gcc -s compiler.libcxx=libstdc++11 -s compiler.version=${VERSION} -s os=Windows -o *:shared=True -o *:staticC=${CONAN_STATIC_C})
    endif ()
endif ()
include(${CMAKE_BINARY_DIR}/conanbuildinfo.cmake)
conan_basic_setup()

if (WINDOWS)
    ADD_DEFINITIONS(-D WINDOWS=1)
endif (WINDOWS)

# Create main Library library with files in src/Library
file(GLOB_RECURSE LIBRARY_SRC_FILES "src/Library/*.cpp" "src/Library/*.hpp" "CInterface/Library/*.cpp" "CInterface/Core.*")
add_library(CreatureLibLibrary SHARED ${LIBRARY_SRC_FILES})

# Create Battling library with files in src/Battling
file(GLOB_RECURSE BATTLING_SRC_FILES "src/Battling/*.cpp" "src/Battling/*.hpp" "CInterface/Battling/*.cpp" "CInterface/Core.*")
add_library(CreatureLibBattling SHARED ${BATTLING_SRC_FILES})

SET(_LIBRARYLINKS Arbutils)
SET(_BATTLINGLINKS CreatureLibLibrary Arbutils)
SET(_TESTLINKS CreatureLibLibrary CreatureLibBattling Arbutils)

if (WINDOWS)
    message(STATUS "Using Windows build.")
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -L ${CMAKE_BINARY_DIR}/bin")
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m64 -Wa,-mbig-obj -Wl,-allow-multiple-definition")
endif (WINDOWS)

if (STATICC)
    message(STATUS "Linking C statically.")
    SET(_LIBRARYLINKS ${_LIBRARYLINKS} -static-libgcc -static-libstdc++)
    SET(_BATTLINGLINKS ${_BATTLINGLINKS} -static-libgcc -static-libstdc++)
    if (NOT DEFINED CONAN_EXPORTED)
        SET(_TESTLINKS ${_TESTLINKS} -static-libgcc -static-libstdc++)
    endif ()
endif ()

target_link_libraries(CreatureLibLibrary PUBLIC ${_LIBRARYLINKS})
target_link_libraries(CreatureLibBattling PUBLIC ${_BATTLINGLINKS})

if (NOT DEFINED CONAN_EXPORTED)
    # Create Test executable
    file(GLOB_RECURSE TEST_FILES "tests/*.cpp" "tests/*.hpp")
    add_executable(CreatureLibTests ${TEST_FILES} extern/catch.hpp)
    message(STATUS "${_TESTLINKS}")
    target_link_libraries(CreatureLibTests PUBLIC ${_TESTLINKS})

    # Add a definition for the test library
    target_compile_definitions(CreatureLibTests PRIVATE TESTS_BUILD)
endif ()